K线形态学习。标准有意义的K线进行分析练习仅供学习之用

zt:=(HIGH-CLOSE[1])/CLOSE[1]*100;

zt1:=(HIGH+0.005-CLOSE[1])/CLOSE[1]*100;

涨停=IF(zt>=10 OR zt<10 AND zt1>=10,1,0);

//dt:=(LOW-CLOSE[1])/CLOSE[1]*100;

//dt1:=(LOW-0.005-CLOSE[1])/CLOSE[1]*100;

//跌停=IF(dt<=-10 OR dt>-10 AND Dt1<=-10,1,0);

STICKLINE(1,H,L,0,1), colorgray;

STICKLINE(1,C,O,6,1), colorgray;

zd=IF(CLOSE>OPEN,1,0);

dd=IF(CLOSE<=OPEN,1,0);

stc=ABS(OPEN-CLOSE)/CLOSE[1];

zfC=(HIGH-LOW)/CLOSE[1];

MId=(CLOSE+OPEN)*0.5;

ssdy=BARSLAST(zd[1] AND stc[1]>0.05);

xddy=BARSLAST(dd[1] AND stc[1]>0.05);

csy=IF((HIGH-MAX(OPEN,CLOSE))/MId>0.03,1,0);

Cxy=IF((MIN(OPEN,CLOSE)-LOW)/mid>0.03,1,0);

dsy=IF(HIGH-MAX(OPEN,CLOSE)<ABS(CLOSE-OPEN)*0.5,1,0);

dxy=IF(MIN(OPEN,CLOSE)-LOW<ABS(CLOSE-OPEN)*0.5,1,0);

V5=MA(VOL,5);

V10=MA(VOL,10);

m5=MA(CLOSE,5);

m10=MA(CLOSE,10);

m20=MA(CLOSE,20);

//淡友反攻 乌云盖顶 倾盘大雨

DWQ=IF(LLV(stc,2)>0.04 AND dd AND zd[1],1,0);

//好友反攻 曙光初现 旭日东升

HSX=IF(LLV(stc,2)>0.04  AND zd AND dd[1],1,0);

//并列阳

BLY=IF(LLV(stc,2)>0.03 AND zd AND zd[1] AND HIGH>HIGH[1] AND OPEN<CLOSE[1] AND CLOSE>CLOSE[1],1,0);

//包线

bao=IF(stc[1]<=0.03 AND stc>0.03 AND MAX(CLOSE,OPEN)>MAX(CLOSE[1],OPEN[1]) AND MIN(CLOSE,OPEN)<MIN(CLOSE[1],OPEN[1]),1,0);

//孕线

yun=IF(stc[1]>0.03 AND stc<=0.03 AND MAX(CLOSE,OPEN)<MAX(CLOSE[1],OPEN[1]) AND MIN(CLOSE,OPEN)>MIN(CLOSE[1],OPEN[1]),1,0);

//双飞乌鸦

WY2=IF(dd AND dd[1] AND bao AND OPEN[1]>CLOSE[2] AND dsy,1,0);

//顺势二阴

SS2Y=IF(dd AND dd[1] AND zd[2] AND stc[2]>0.04 AND csy[1] AND CLOSE[1]>=CLOSE[2]*0.995 AND OPEN>CLOSE[1]*0.995 AND (Csy OR Cxy),1,0);

//上涨两颗星

sz2x=IF(zd[2] AND stc[1]>0.05 AND HHV(stc,2)<0.025 AND HHV(zfc,2)<0.05 AND LLV(CLOSE,2)>CLOSE[2]*0.995 AND HHV(CLOSE,2)<CLOSE[2]*1.03,1,0);

//跳空两颗星

tk2x=IF(LOW[1]>HIGH[2] AND  HHV(stc,2)<0.025 AND HHV(zfc,2)<0.05,1,0);

//下跌三颗星

xd3x=IF(dd[3] AND stc[3]>0.05 AND HHV(stc,3)<0.025 AND HHV(zfc,3)<0.05 AND HHV(CLOSE,3)<CLOSE[3]*1.01 AND LLV(CLOSE,3)>CLOSE[3]*0.98,1,0);

//搓揉线上涨

CRxz=IF(Cxy[1] AND dsy[1] AND Csy AND dxy  AND HHV(stc,2)<0.03 AND LLV(zfc,2)>0.06 AND ABS(MId-MId[1])/MId[1]<0.02,1,0);

//搓揉线下跌

CRxd=IF(dxy[1] AND Csy[1] AND dsy AND Cxy AND HHV(stc,2)<0.03 AND LLV(zfc,2)>0.06 AND ABS(MId-MId[1])/MId[1]<0.02,1,0);

//搓揉线上涨变异

CRxz3=IF(Cxy[2] AND dsy[2] AND Csy AND dxy AND HHV(stc,3)<0.03 AND MIN(zfc,zfc[2])>0.06 AND zfc[1]<0.05 AND ABS(MId-MId[2])/MId[2]<0.02,1,0);

//搓揉线下跌变异

CRxd3=IF(dxy[2] AND Csy[2] AND dsy AND Cxy AND HHV(stc,3)<0.03 AND MIN(zfc,zfc[2])>0.06 AND zfc[1]<0.05 AND ABS(MId-MId[2])/MId[2]<0.02,1,0);

//尽头线上涨

jtxz=IF(zd[1] AND stc[1]>0.05 AND Csy[1] AND MIN(CLOSE,OPEN)>CLOSE[1] AND MAX(CLOSE,OPEN)<HIGH[1],1,0);

//尽头线下跌

jtxd=IF(dd[1] AND stc[1]>0.05 AND Cxy[1] AND MIN(CLOSE,OPEN)>LOW[1] AND MAX(CLOSE,OPEN)<CLOSE[1],1,0);

//夹击线上涨

JJxz=IF(dd[2] AND zd[1] AND dd AND stc[1]>0.05 AND MAX(stc[2],stc)<0.025 AND MId[2]>OPEN[1] AND OPEN[2]<MId[1] AND MId<CLOSE[1] AND CLOSE>MId[1],1,0);

//夹击线下跌

JJxd=IF(zd[2] AND dd[1] AND zd AND stc[1]>0.05 AND MAX(stc[2],stc)<0.025 AND MId[2]<OPEN[1] AND OPEN[2]>MId[1] AND MId>CLOSE[1] AND CLOSE<MId[1],1,0);

//黄昏之星

Hhzx=IF(zd[2] AND dd AND MIN(stc[2],stc)>0.04 AND stc[1]<0.025 AND MId[1]>mid[2]*1.01 AND CLOSE<MId[2],1,0);

//黄昏2星

Hh2x=IF(zd[3] AND dd AND MIN(stc[3],stc)>0.04 AND MAX(stc[1],stc[2])<0.025 AND MIN(MId[1],MId[2])>mid[3]*1.01 AND CLOSE<MId[3],1,0);

//早晨之星

zczx=IF(dd[2] AND zd AND MIN(stc[2],stc)>0.04 AND stc[1]<0.025 AND MId[1]<MId[2]*0.99 AND CLOSE>MId[2],1,0);

//早晨2星

zc2x=IF(dd[3] AND zd AND MIN(stc[3],stc)>0.04 AND MAX(stc[1],stc[2])<0.025 AND MAX(MId[1],MId[2])<MId[3]*0.99 AND CLOSE>MId[3],1,0);

//多方炮

dfp=IF(zd[2] AND zd AND dd[1] AND stc[2]>0.03 AND stc>stc[2] AND VOL[1]<VOL[2]*0.75 AND CLOSE[1]>MId[2] AND HIGH>HIGH[2] AND CLOSE>CLOSE[2],1,0);

//空方炮

kfp=IF(dd[2] AND dd AND zd[1] AND MIN(stc[2],stc)>0.03 AND CLOSE[1]<OPEN[2] AND CLOSE<CLOSE[2] AND LOW<LOW[2],1,0);

//上升三部曲

ss3b=IF(ssdy>=3 AND ssdy<=7 AND zd AND stc>0.05 AND CLOSE>HHV(HIGH[1],ssdy+1) AND HHV(stc[1],ssdy)<0.03 AND LLV(CLOSE[1],ssdy)>OPEN[ssdy+1] AND HHV(CLOSE[1],ssdy)<CLOSE[ssdy+1],1,0);

//下跌三部曲

xd3b=IF(xddy>=3 AND xddy<=4 AND dd AND stc>0.05 AND CLOSE<LLV(LOW[1],xddy+1) AND HHV(stc[1],xddy)<0.03 AND HHV(CLOSE[1],xddy)<OPEN[xddy+1],1,0);

//多方尖兵

dfjb=IF((Csy[2] AND zfc[2]>0.06 OR Csy[1] AND zfc[1]>0.06) AND CLOSE>HHV(HIGH[1],2),1,0);

//空方尖兵

kfjb=IF(COUNT(Cxy[1] AND zfc[1]>0.06,4)>0 AND CLOSE<LLV(LOW[1],4),1,0);

//跳空三连阳

tk3z=IF(COUNT(zd AND NOT(涨停) AND Stc>0.02 AND OPEN>CLOSE[1],3)=3 AND stc[1]>stc[2] AND VOL[1]/VOL[2]>0.75,1,0);

//跳空三连阴

tk3d=IF(COUNT(dd AND stc>0.02 AND OPEN<CLOSE[1],3)=3,1,0);

//上升抵抗

ssdk=IF(dd AND CLOSE>CLOSE[1] AND COUNT(zd[1] AND NOT(涨停[1]) AND Stc[1]>0.02 AND OPEN[1]>CLOSE[2],3)=3 AND stc[2]>stc[3] AND VOL[2]/VOL[3]>0.9 AND VOL[1]/VOL[2]>0.9,1,0);

//上升弓形

ssgx=IF(ssdy<=15 AND ssdy>=5 AND zd AND stc>0.05 AND CLOSE>HHV(HIGH[1],ssdy+1) AND V5[1]<V10[1] AND VOL=HHV(VOL,ssdy+1) AND LLV(CLOSE[1],ssdy)>MId[ssdy+1] AND HHV(stc[1],ssdy)<0.05,1,0);

//下探上涨

xtsz=IF(zd AND stc>0.05 AND (CLOSE[1]-OPEN)/CLOSE[1]>0.05 AND HIGH=HHV(HIGH,5) AND dxy AND VOL<VOL[1],1,0);

//高开逃逸

gkty=IF(dd AND stc>0.05 AND (OPEN-CLOSE[1])/CLOSE[1]>0.05,1,0);

//红三兵

H3bz=IF(COUNT(zd AND stc>0.005 AND stc<0.05 AND HIGH>HIGH[1],3)=3 AND VOL[2]/VOL[3]>1.5 AND HHV(VOL,2)/VOL[2]<1.2 AND LLV(VOL,2)/VOL[2]>0.8,1,0);

//徐缓上升

xhss=IF(zd AND stc>0.05 AND COUNT(zd[1] AND stc[1]<0.03,3)=3,1,0);

//三只乌鸦

wy3=IF(COUNT(dd AND stc>0.02,3)=3 AND COUNT(OPEN>CLOSE[1],3)>0,1,0);

//黑三兵

H3bd=IF(COUNT(dd AND stc>0.005 AND stc<0.05 AND LOW<LOW[1],3)=3,1,0);

//徐缓下跌

xhxd=IF(dd AND stc>0.05 AND COUNT(dd[1] AND stc[1]<0.03,3)=3,1,0);

//倒三阳不常见 倒两阳

d2zd=IF(COUNT(zd AND Stc>0.02 AND OPEN<CLOSE[1] AND CLOSE<OPEN[1],2)=2,1,0);

//下跌抵抗

xddk=IF(COUNT(dd[1] AND stc[1]>0.03 AND OPEN[1]<CLOSE[2],3)=3 AND zd AND stc>0.02,1,0);

//冉冉上升

rrss=IF(m5>m10 AND m10>m20 AND v5>v10 AND HHV(stc,10)<0.05,1,0);

//猝死线

deadx=IF(zd AND stc>0.06 AND VOL/v5>2 AND m5>m10 AND m10>m20 AND V5>V10 AND HHV(stc[1],10)<0.05,1,0);

//绵绵阴跌

mmyd=IF(m5<m10 AND m10<m20 AND HHV(stc,10)<0.05,1,0);

//下降覆盖线

xjfg=IF(zd[3] AND zd[1] AND dd[2] AND dd AND stc[3]>0.03 AND stc[2]>0.05 AND CLOSE[2]<MId[3] AND CLOSE[1]<MId[2] AND CLOSE<MId[1] AND VOL[1]<VOL[3],1,0);

//升势受阻 抛压大 中性

sssz=IF(COUNT(zd,3)=3 AND stc[2]>stc[1] AND stc[1]>0.02 AND stc[1]>stc AND (Csy OR HIGH-CLOSE>HIGH[1]-CLOSE[1]) AND VOL[2]<VOL[1] AND VOL[1]<VOL,1,0);

//升势停顿 停止做多 中性

sstd=IF(COUNT(zd[2] AND zd[1] AND zd AND LLV(stc[1],2)>0.04 AND stc<0.03,2)=1 AND VOL/VOL[1]<0.75,1,0);

//阳线跛脚线

yxbjx=IF(COUNT(zd ,3)=3 AND COUNT(VOL[1]>VOL AND stc[1]>0.03 AND OPEN<CLOSE[1],2)=2 AND OPEN>OPEN[1] AND CLOSE/CLOSE[1]<1.01,1,0);

ala=bao+yun+jtxd+JJxd+tk3z+tk3d;

kong=DWQ+WY2+xd3x+CRxd+CRxd3+jtxz+JJxz+Hhzx+Hh2x+kfp+xd3b+kfjb+gkty+wy3+H3bd+xhxd+d2zd+xddk+deadx+mmyd+xjfg+sssz+sstd+yxbjx;

duo=HSX+bly+SS2Y+sz2x+tk2x+CRxz+CRxz3+zczx+zc2x+dfp+ss3b+dfjb+ssdk+ssgx+xtsz+H3bz+xhss+rrss;

STICKLINE(ala,H,L,0,1), coloryellow;

STICKLINE(ala,C,O,6,1), coloryellow;

STICKLINE(kong,H,L,0,1), colorgreen;

STICKLINE(kong,C,O,6,1), colorgreen;

STICKLINE(duo,C,O,6,0), colorred;

STICKLINE(duo,H,L,0,1), colorred;